Question

我需要改变这个结构

<A>
<B>value1</B>
</A>
<A>
<B>value2</B>
</A>

与

<A>
<B>value1<B>
<B>value2<B>
</A>

What is best solution using XSLT-1.0? Thank you!

PS:我试过这个代码:

<?xml version="1.0" encoding="UTF-8"?> 
<xsl:stylesheet version="1.1" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:fo="http://www.w3.org/1999/XSL/Format"> 
<xsl:output method="xml" version="1.0" encoding="utf-8" indent="yes"/>   
<xsl:key name="group_a" match="//A" use="B"/> 
<xsl:template match="/Test"> <a-node> <xsl:for-each select="//A"> <b-node> 
<xsl:value-of select="//A/B"/> </b-node> </xsl:for-each> </a-node> 
</xsl:template> 
</xsl:stylesheet>

但它只返回第一个值 :

<?xml version="1.0" encoding="utf-8"?> <a-node mlns:fo="http://www.w3.org/1999/XSL/Format"> <b-node>value1</b-node> <b-node>value1</b-node> </a-node>

但我需要:

<?xml version="1.0" encoding="utf-8"?> <a-node xmlns:fo="http://www.w3.org/1999/XSL/Format"> <b-node>value1</b-node> <b-node>value2</b-node> </a-node>

Answer 1

既然你似乎需要把所有孩子都倒在同一个节点下那你就不需要"A"上的前额课了你可以直接转到"B"的孩子那里

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
                version="1.0">
    <xsl:output omit-xml-declaration="yes" method="xml" version="1.0" />
    <xsl:template match="/">
        <A>
            <xsl:for-each select="//A/B">
                <B>
                    <xsl:value-of select="./text()"/>
                </B>
            </xsl:for-each>
        </A>
    </xsl:template>
</xsl:stylesheet>

@Seans 评论指出, // 不应在现实生活中使用。替换 //, 由您真正的根元素路径替换。

Answer 2

此样式表...

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
                version="1.0">
    <xsl:output omit-xml-declaration="yes" method="xml" version="1.0" />
    <xsl:template match="/">
       <A>
        <xsl:apply-templates select="*/A/B"/>
       </A>
    </xsl:template>

    <xsl:template match="B">
      <B><xsl:value-of select="."/></B>
    </xsl:template>
</xsl:stylesheet>

...将改变...

<root>
<A>
<B>value1</B>
</A>
<A>
<B>value2</B>
</A>
</root>

...进入这个...

 <A><B>value1</B><B>value2</B></A>

Answer 3

< 坚固 > 此变换使用最基本的 XSLT 设计模式之一 -- -- 超越身份变换。因此, 写、理解、维护和扩展 < /坚固 > 更容易 :

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="node()|@*">
  <xsl:copy>
   <xsl:apply-templates select="node()|@*"/>
  </xsl:copy>
 </xsl:template>

 <xsl:template match="A[1]">
  <A>
    <xsl:apply-templates select="node()|following-sibling::A/node()"/>
  </A>
 </xsl:template>
 <xsl:template match="A"/>
</xsl:stylesheet>

在以下 XML 文档 (通过将提供的 XML 碎片包装成单上方元素,将 XML 文档转换为完善的 XML 文档) 上应用时 < 坚固> :

<t>
    <A>
        <B>value1</B>
    </A>
    <A>
        <B>value2</B>
    </A>
</t>

<强者>被通缉者,产生正确结果:

<t>
   <A>
      <B>value1</B>
      <B>value2</B>
   </A>
</t>

友情链接