UPDATE

Question

Hey peepz! I have this footer image, that I want to align to the bottom of the stage, however I m getting errors.

As you can see I have an ADDED_TO_STAGE listener in the constructor function.

package src.display{

import flash.text.*;
import flash.display.*;
import flash.geom.Matrix;
import flash.events.Event;

public class Frame extends Sprite {
    private var footer:Sprite = new Sprite();

    // ☼ ------ Constructor
    public function Frame():void {
        this.addEventListener(Event.ADDED_TO_STAGE, tracer);
    }

    public function tracer(event:Event) {
        trace("Frame added to stage --- √"+"
");
        this.removeEventListener(Event.ADDED_TO_STAGE, tracer);
    }

    // ☼ ------ Init
    public function init():void {
        footer.graphics.beginFill(0x000);
        footer.graphics.drawRect(0,0,800,56);
        footer.graphics.endFill();
        footer.y = (stage.height - footer.height); // <-- This Line

        addChild(footer);
    }

}

}

The movie will work correctly if I comment out line 26 (but of course I don t want Y to be 0):

footer.y = (stage.height - footer.height);

Here is the error in the output window I m getting:

TypeError: Error #1009: Cannot access a property or method of a null object reference. at src.display::Frame/init()[/Users/lgaban/Projects/Player/src/display/Frame.as:26]

UPDATE

Answered my own quesiton, fix here

Answer 1

Using a custom event is a bit overkill, especially when you have the listener for added to stage already in there. I would do it like this:

package src.display{

    import flash.text.*;
    import flash.display.*;
    import flash.geom.Matrix;
    import flash.events.Event;

    public class Frame extends Sprite {

        // don t instantiate your sprite here, it s weird! :)
        private var footer:Sprite;

        // this is the same as in your example
        public function Frame():void {
            this.addEventListener(Event.ADDED_TO_STAGE, handleAddedToStage);
        }

            // i renamed this to reflect what it does
        private function handleAddedToStage(event:Event) {
            trace("Frame added to stage --- √"+"
");
            this.removeEventListener(Event.ADDED_TO_STAGE, handleAddedToStage);
            init();
        }

        // this is also essentially the same, except for private since it shouldn t be called from the outside
        private function init():void {
            footer = new Sprite();
            footer.graphics.beginFill(0x000);
            footer.graphics.drawRect(0,0,800,56);
            footer.graphics.endFill();
            footer.y = (stage.height - footer.height);

            addChild(footer);
        }

    }
}

Answer 2

Not that it is the complete answer, but that error is telling you that stage is null.

UPDATE

友情链接